"
% Document:      Vata grammar fragment for unbounded dependencies
% Author:        Ash Asudeh (http://www.carleton.ca/~asudeh)
% Time-stamp:    <2008-08-20 09:23:00 asudeh> 
% Institution:   ICS, Carleton University
% Status:        Public
% Copyright:     2008 Ash Asudeh
% License:       Creative Commons Attribution-Noncommercial-Share
                 Alike 3.0 United States License 
% Version:       Draft
% 
% File:          vata.lfg
% Format:        XLE
% Function:      grammar fragment
%
% Notes: 
  1. For further theoretical details, see the paper 'Toward a unified
  theory of resumption', available at
  http://www.carleton.ca/~asudeh. The underlying theory is the
  Resource Management Theory of Resumption (Asudeh 2004, 2009)

  2. The grammar does not have a Glue Semantics component and therefore only
  approximates RMTR, as explained in comments below. The
  grammar is meant solely as a test of formal claims about abstract
  syntactic relationships; it uses English
  as both the object language and the metalanguage and does not
  attempt to approximate Vata word order or facts of Vata syntax
  outside a limited fragment of the unbounded dependency system.
"

TEST VATA   CONFIG (1.0)
  ROOTCAT   T.
  FILES  .
  LEXENTRIES   (TEST VATA).
  RULES   (TEST VATA).
  TEMPLATES   (TEST VATA).
  GOVERNABLERELATIONS    SUBJ OBJ OBJ2 COMP XCOMP OBL OBL-?+.
  SEMANTICFUNCTIONS    ADJUNCT  UDF POSS STANDARD.
  NONDISTRIBUTIVES    NUM PERS CONJ-FORM.
  EPSILON   e.
OPTIMALITYORDER NOGOOD.

----

TEST VATA   RULES (1.0)
   GF = {SUBJ | OBJ | OBJ2 | OBL | OBL-?+ | UDF}. 

   OGF = {OBJ | OBJ2 | OBL | OBL-?+}.    

   T -->  (NP: (^ COMP* {OGF: (-> PRED) = 'PRO' | 
                  SUBJ:(-> PRONTYPE) =c PERSONAL})\PRED\PRONTYPE = !\PRED\PRONTYPE	  
	   (^ UDF)=!
	   )
	   S.
   "This grammar assumes that the Vata unbounded dependency equation
                  is associated directly with a c- structure node, but
                  it could alternatively be associated with a (null)
                  complementizer.  

    The use of the feature PRONTYPE and the constrainting off-path
    equation is necessary to compensate for the lack of Glue
    Semantics, which would normally ensure that a pronominal resource
    must be associated with the subject resumptive." 

   S --> (NP: (^ SUBJ)=!
	     (! CASE)=NOM)
 	 VP.

   VP --> V
 	  (NP: (^ OBJ)=!
	       (! CASE)=ACC)
	  (S:(^ COMP)=!).

   NP --> N.


----

TEST VATA   TEMPLATES (1.0)


----

TEST VATA LEXICON (1.0)

who  N *     (UDF ^)
             (^ PRONTYPE) = Q
	     (^ PRED) = 'PRO'.

John N *     (^ PRED) = 'JOHN'.

Mary N *     (^ PRED) = 'MARY'.

Bill N *     (^ PRED) = 'BILL'.

he N * (^ PRED) = 'PRO'
       (^ PRONTYPE) = PERSONAL
       (^ CASE) = NOM
       (^ PERS) = 3
       (^ NUM) = SG
       (^ GEND) = MASC.

him N * (^ PRED) = 'PRO'
        (^ PRONTYPE) = PERSONAL	
        (^ CASE) = ACC
        (^ PERS) = 3
        (^ NUM) = SG
        (^ GEND) = MASC.

leave V * (^ PRED) = 'LEAVE<(^ SUBJ)>'.

see V * (^ PRED) = 'SEE<(^ SUBJ)(^ OBJ)>'.

tell V * (^ PRED) = 'TELL<(^ SUBJ)(^ OBJ)(^ COMP)>'.

claim V * (^ PRED) = 'CLAIM<(^ SUBJ)(^ COMP)>'.

----